563 lines
21 KiB
GLSL
563 lines
21 KiB
GLSL
Shader "Lux URP/Flat Shaded"
|
||
{
|
||
Properties
|
||
{
|
||
[HeaderHelpLuxURP_URL(3omvzsrriztm)]
|
||
|
||
[Header(Surface Options)]
|
||
[Space(5)]
|
||
[Enum(UnityEngine.Rendering.CullMode)]
|
||
_Cull ("Culling", Float) = 2
|
||
[Toggle(_ALPHATEST_ON)]
|
||
_AlphaClip ("Alpha Clipping", Float) = 0.0
|
||
_Cutoff (" Threshold", Range(0.0, 1.0)) = 0.5
|
||
[ToggleOff(_RECEIVE_SHADOWS_OFF)]
|
||
_ReceiveShadows ("Receive Shadows", Float) = 1.0
|
||
|
||
|
||
[Header(Surface Inputs)]
|
||
[Space(5)]
|
||
[MainColor]
|
||
_BaseColor ("Color", Color) = (1,1,1,1)
|
||
|
||
[Toggle(_ENABLEBASEMAP)]
|
||
_EnableBaseMap ("Enable Base Map", Float) = 1
|
||
[LuxURPHelpDrawer]
|
||
_Help ("If unchecked Alpha Clipping and Smoothness from Alpha will be disabled.", Float) = 0.0
|
||
[MainTexture]
|
||
_BaseMap ("Albedo (RGB) Alpha (A)", 2D) = "white" {}
|
||
|
||
[Space(5)]
|
||
[Toggle(_SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A)]
|
||
_SmoothnessTextureChannel ("Albedo Alpha contains Smoothness", Float) = 0
|
||
[LuxURPHelpDrawer]
|
||
_Help ("Checking this will disable Alpha Clipping.", Float) = 0.0
|
||
_Smoothness ("Smoothness", Range(0.0, 1.0)) = 0.5
|
||
_SpecColor ("Specular", Color) = (0.2, 0.2, 0.2)
|
||
|
||
[Space(5)]
|
||
|
||
[Toggle(_NORMALMAP)]
|
||
_ApplyNormal ("Enable Normal Map", Float) = 0.0
|
||
[NoScaleOffset] _BumpMap (" Normal Map", 2D) = "bump" {}
|
||
_BumpScale (" Normal Scale", Float) = 1.0
|
||
|
||
[Header(Rim Lighting)]
|
||
[Space(5)]
|
||
[Toggle(_RIMLIGHTING)]
|
||
_Rim ("Enable Rim Lighting", Float) = 0
|
||
[HDR] _RimColor ("Rim Color", Color) = (0.5,0.5,0.5,1)
|
||
_RimPower ("Rim Power", Float) = 2
|
||
_RimFrequency ("Rim Frequency", Float) = 0
|
||
_RimMinPower (" Rim Min Power", Float) = 1
|
||
_RimPerPositionFrequency (" Rim Per Position Frequency", Range(0.0, 1.0)) = 1
|
||
|
||
|
||
[Header(Stencil)]
|
||
[Space(5)]
|
||
[IntRange] _Stencil ("Stencil Reference", Range (0, 255)) = 0
|
||
[IntRange] _ReadMask (" Read Mask", Range (0, 255)) = 255
|
||
[IntRange] _WriteMask (" Write Mask", Range (0, 255)) = 255
|
||
[Enum(UnityEngine.Rendering.CompareFunction)]
|
||
_StencilComp ("Stencil Comparison", Int) = 8 // always – terrain should be the first thing being rendered anyway
|
||
[Enum(UnityEngine.Rendering.StencilOp)]
|
||
_StencilOp ("Stencil Operation", Int) = 0 // 0 = keep, 2 = replace
|
||
[Enum(UnityEngine.Rendering.StencilOp)]
|
||
_StencilFail ("Stencil Fail Op", Int) = 0 // 0 = keep
|
||
[Enum(UnityEngine.Rendering.StencilOp)]
|
||
_StencilZFail ("Stencil ZFail Op", Int) = 0 // 0 = keep
|
||
|
||
|
||
[Header(Advanced)]
|
||
[Space(5)]
|
||
[ToggleOff]
|
||
_SpecularHighlights ("Enable Specular Highlights", Float) = 1.0
|
||
[ToggleOff]
|
||
_EnvironmentReflections ("Environment Reflections", Float) = 1.0
|
||
[Space(5)]
|
||
[Toggle(_RECEIVE_SHADOWS_OFF)]
|
||
_Shadows ("Disable Receive Shadows", Float) = 0.0
|
||
|
||
|
||
[Header(Render Queue)]
|
||
[Space(5)]
|
||
[IntRange] _QueueOffset ("Queue Offset", Range(-50, 50)) = 0
|
||
|
||
|
||
// Needed by the inspector
|
||
[HideInInspector] _Culling ("Culling", Float) = 0.0
|
||
|
||
// Lightmapper and outline selection shader need _MainTex, _Color and _Cutoff
|
||
[HideInInspector] _MainTex ("Albedo", 2D) = "white" {}
|
||
[HideInInspector] _Color ("Color", Color) = (1,1,1,1)
|
||
}
|
||
|
||
SubShader
|
||
{
|
||
Tags
|
||
{
|
||
"RenderPipeline" = "UniversalPipeline"
|
||
"RenderType" = "Opaque"
|
||
"Queue" = "Geometry"
|
||
}
|
||
LOD 100
|
||
|
||
Pass
|
||
{
|
||
Name "ForwardLit"
|
||
Tags{"LightMode" = "UniversalForward"}
|
||
|
||
Stencil {
|
||
Ref [_Stencil]
|
||
ReadMask [_ReadMask]
|
||
WriteMask [_WriteMask]
|
||
Comp [_StencilComp]
|
||
Pass [_StencilOp]
|
||
Fail [_StencilFail]
|
||
ZFail [_StencilZFail]
|
||
}
|
||
|
||
|
||
ZWrite On
|
||
Cull [_Cull]
|
||
|
||
HLSLPROGRAM
|
||
// Required to compile gles 2.0 with standard SRP library
|
||
#pragma prefer_hlslcc gles
|
||
#pragma exclude_renderers d3d11_9x
|
||
|
||
// Shader target needs to be 3.0 due to tex2Dlod in the vertex shader or VFACE
|
||
#pragma target 3.0
|
||
|
||
// -------------------------------------
|
||
// Material Keywords
|
||
#define _SPECULAR_SETUP 1
|
||
|
||
#pragma shader_feature _ALPHATEST_ON
|
||
#pragma shader_feature _NORMALMAP
|
||
#pragma shader_feature _SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A
|
||
#pragma shader_feature_local _RIMLIGHTING
|
||
|
||
#pragma shader_feature_local _ENABLEBASEMAP
|
||
#if !defined(_ENABLEBASEMAP)
|
||
#if defined(_ALPHATEST_ON)
|
||
#undef _ALPHATEST_ON
|
||
#endif
|
||
#if defined(_SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A)
|
||
#undef _SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A
|
||
#endif
|
||
#endif
|
||
|
||
#if defined(_SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A)
|
||
#if defined(_ALPHATEST_ON)
|
||
#undef _ALPHATEST_ON
|
||
#endif
|
||
#endif
|
||
|
||
// We have to sample SH per pixel
|
||
#if defined (EVALUATE_SH_VERTEX)
|
||
#undef EVALUATE_SH_VERTEX
|
||
#endif
|
||
#if defined(EVALUATE_SH_MIXED)
|
||
#undef EVALUATE_SH_MIXED
|
||
#endif
|
||
|
||
#pragma shader_feature _SPECULARHIGHLIGHTS_OFF
|
||
#pragma shader_feature _ENVIRONMENTREFLECTIONS_OFF
|
||
#pragma shader_feature _RECEIVE_SHADOWS_OFF
|
||
|
||
// -------------------------------------
|
||
// Lightweight Pipeline keywords
|
||
#pragma multi_compile _ _MAIN_LIGHT_SHADOWS
|
||
#pragma multi_compile _ _MAIN_LIGHT_SHADOWS_CASCADE
|
||
#pragma multi_compile _ _ADDITIONAL_LIGHTS_VERTEX _ADDITIONAL_LIGHTS
|
||
#pragma multi_compile _ _ADDITIONAL_LIGHT_SHADOWS
|
||
#pragma multi_compile _ _SHADOWS_SOFT
|
||
#pragma multi_compile _ _MIXED_LIGHTING_SUBTRACTIVE
|
||
|
||
// -------------------------------------
|
||
// Unity defined keywords
|
||
#pragma multi_compile _ DIRLIGHTMAP_COMBINED
|
||
#pragma multi_compile _ LIGHTMAP_ON
|
||
#pragma multi_compile_fog
|
||
|
||
//--------------------------------------
|
||
// GPU Instancing
|
||
#pragma multi_compile_instancing
|
||
|
||
// Include base inputs and all other needed "base" includes
|
||
#include "Includes/Lux URP Flat Shaded Inputs.hlsl"
|
||
|
||
#pragma vertex LitPassVertex
|
||
#pragma fragment LitPassFragment
|
||
|
||
//--------------------------------------
|
||
// Vertex shader
|
||
|
||
|
||
VertexOutput LitPassVertex(VertexInput input)
|
||
{
|
||
VertexOutput output = (VertexOutput)0;
|
||
UNITY_SETUP_INSTANCE_ID(input);
|
||
UNITY_TRANSFER_INSTANCE_ID(input, output);
|
||
UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(output);
|
||
|
||
VertexPositionInputs vertexInput;
|
||
vertexInput = GetVertexPositionInputs(input.positionOS.xyz);
|
||
VertexNormalInputs normalInput = GetVertexNormalInputs(input.normalOS, input.tangentOS);
|
||
|
||
float3 viewDirWS = GetCameraPositionWS() - vertexInput.positionWS;
|
||
half3 vertexLight = VertexLighting(vertexInput.positionWS, normalInput.normalWS);
|
||
half fogFactor = ComputeFogFactor(vertexInput.positionCS.z);
|
||
|
||
output.uv.xy = TRANSFORM_TEX(input.texcoord, _BaseMap);
|
||
output.viewDirWS = viewDirWS;
|
||
|
||
// Just in case :)
|
||
#ifdef _NORMALMAP
|
||
//output.normalWS = normalInput.normalWS; //NormalizeNormalPerVertex(normalInput.normalWS);
|
||
float sign = input.tangentOS.w * GetOddNegativeScale();
|
||
output.tangentWS = float4(normalInput.tangentWS.xyz, sign);
|
||
#endif
|
||
|
||
OUTPUT_LIGHTMAP_UV(input.lightmapUV, unity_LightmapST, output.lightmapUV);
|
||
//OUTPUT_SH(output.normalWS.xyz, output.vertexSH);
|
||
OUTPUT_SH(normalInput.normalWS, output.vertexSH);
|
||
|
||
output.fogFactorAndVertexLight = half4(fogFactor, vertexLight);
|
||
|
||
// Always needed!
|
||
output.positionWS = vertexInput.positionWS;
|
||
|
||
#if defined(REQUIRES_VERTEX_SHADOW_COORD_INTERPOLATOR)
|
||
output.shadowCoord = GetShadowCoord(vertexInput);
|
||
#endif
|
||
output.positionCS = vertexInput.positionCS;
|
||
|
||
return output;
|
||
}
|
||
|
||
//--------------------------------------
|
||
// Fragment shader and functions
|
||
|
||
inline void InitializeSurfaceData(
|
||
float2 uv,
|
||
out SurfaceDescription outSurfaceData)
|
||
{
|
||
#if defined(_ENABLEBASEMAP)
|
||
half4 albedoAlpha = SampleAlbedoAlpha(uv.xy, TEXTURE2D_ARGS(_BaseMap, sampler_BaseMap));
|
||
outSurfaceData.alpha = Alpha(albedoAlpha.a, 1, _Cutoff);
|
||
outSurfaceData.albedo = albedoAlpha.rgb * _BaseColor.rgb;
|
||
#else
|
||
outSurfaceData.albedo = _BaseColor.rgb;
|
||
outSurfaceData.alpha = 1;
|
||
#endif
|
||
|
||
outSurfaceData.metallic = 0;
|
||
outSurfaceData.specular = _SpecColor;
|
||
outSurfaceData.smoothness = _Smoothness;
|
||
|
||
#if defined(_SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A)
|
||
outSurfaceData.smoothness *= albedoAlpha.a;
|
||
#endif
|
||
|
||
outSurfaceData.occlusion = 1;
|
||
|
||
// Normal Map
|
||
#if defined (_NORMALMAP)
|
||
outSurfaceData.normalTS = SampleNormal(uv.xy, TEXTURE2D_ARGS(_BumpMap, sampler_BumpMap), _BumpScale);
|
||
#else
|
||
outSurfaceData.normalTS = half3(0,0,1);
|
||
#endif
|
||
|
||
outSurfaceData.emission = 0;
|
||
}
|
||
|
||
void InitializeInputData(VertexOutput input, half3 normalTS, float3 normalWS, half occlusion, half facing, out InputData inputData)
|
||
{
|
||
inputData = (InputData)0;
|
||
inputData.positionWS = input.positionWS;
|
||
|
||
half3 viewDirWS = SafeNormalize(input.viewDirWS);
|
||
|
||
// We are using the passed vertexnormal normalWS here!
|
||
#if defined(_NORMALMAP)
|
||
normalTS.z *= facing;
|
||
float sgn = input.tangentWS.w; // should be either +1 or -1
|
||
float3 bitangent = sgn * cross(normalWS.xyz, input.tangentWS.xyz);
|
||
inputData.normalWS = TransformTangentToWorld(normalTS, half3x3(input.tangentWS.xyz, bitangent, normalWS));
|
||
#else
|
||
inputData.normalWS = normalWS * facing;
|
||
#endif
|
||
|
||
inputData.normalWS = NormalizeNormalPerPixel(inputData.normalWS);
|
||
inputData.viewDirectionWS = viewDirWS;
|
||
|
||
#if defined(REQUIRES_VERTEX_SHADOW_COORD_INTERPOLATOR)
|
||
inputData.shadowCoord = input.shadowCoord;
|
||
#elif defined(MAIN_LIGHT_CALCULATE_SHADOWS)
|
||
inputData.shadowCoord = TransformWorldToShadowCoord(inputData.positionWS);
|
||
#else
|
||
inputData.shadowCoord = float4(0, 0, 0, 0);
|
||
#endif
|
||
|
||
inputData.fogCoord = input.fogFactorAndVertexLight.x;
|
||
inputData.vertexLighting = input.fogFactorAndVertexLight.yzw;
|
||
inputData.bakedGI = SAMPLE_GI(input.lightmapUV, input.vertexSH * occlusion, inputData.normalWS);
|
||
}
|
||
|
||
half4 LitPassFragment(VertexOutput input, half facing : VFACE) : SV_Target
|
||
{
|
||
UNITY_SETUP_INSTANCE_ID(input);
|
||
UNITY_SETUP_STEREO_EYE_INDEX_POST_VERTEX(input);
|
||
|
||
// Get the surface description
|
||
SurfaceDescription surfaceData;
|
||
InitializeSurfaceData(input.uv, surfaceData);
|
||
|
||
// Create cutom per vertex normal
|
||
half3 tnormal = normalize( cross(ddy(input.positionWS), ddx(input.positionWS)) );
|
||
|
||
// Prepare surface data (like bring normal into world space and get missing inputs like gi)
|
||
InputData inputData;
|
||
InitializeInputData(input, surfaceData.normalTS, tnormal, surfaceData.occlusion, facing, inputData);
|
||
|
||
#if defined(_RIMLIGHTING)
|
||
half rim = saturate(1.0h - saturate( dot(inputData.normalWS, inputData.viewDirectionWS) ) );
|
||
half power = _RimPower;
|
||
UNITY_BRANCH if(_RimFrequency > 0 ) {
|
||
half perPosition = lerp(0.0h, 1.0h, dot(1.0h, frac(UNITY_MATRIX_M._m03_m13_m23) * 2.0h - 1.0h ) * _RimPerPositionFrequency ) * 3.1416h;
|
||
power = lerp(power, _RimMinPower, (1.0h + sin(_Time.y * _RimFrequency + perPosition) ) * 0.5h );
|
||
}
|
||
surfaceData.emission += pow(rim, power) * _RimColor.rgb * _RimColor.a;
|
||
#endif
|
||
|
||
// Apply lighting
|
||
half4 color = LightweightFragmentPBR(inputData, surfaceData.albedo, surfaceData.metallic, surfaceData.specular, surfaceData.smoothness, surfaceData.occlusion, surfaceData.emission, surfaceData.alpha);
|
||
|
||
// Add fog
|
||
color.rgb = MixFog(color.rgb, inputData.fogCoord);
|
||
return color;
|
||
}
|
||
|
||
ENDHLSL
|
||
}
|
||
|
||
|
||
// Shadows -----------------------------------------------------
|
||
|
||
Pass
|
||
{
|
||
Name "ShadowCaster"
|
||
Tags{"LightMode" = "ShadowCaster"}
|
||
|
||
ZWrite On
|
||
ZTest LEqual
|
||
Cull Off
|
||
|
||
HLSLPROGRAM
|
||
// Required to compile gles 2.0 with standard srp library
|
||
#pragma prefer_hlslcc gles
|
||
#pragma exclude_renderers d3d11_9x
|
||
#pragma target 2.0
|
||
|
||
// -------------------------------------
|
||
// Material Keywords
|
||
#pragma shader_feature _ALPHATEST_ON
|
||
|
||
#pragma shader_feature _SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A
|
||
|
||
#pragma shader_feature_local _ENABLEBASEMAP
|
||
#if !defined(_ENABLEBASEMAP)
|
||
#if defined(_ALPHATEST_ON)
|
||
#undef _ALPHATEST_ON
|
||
#endif
|
||
#if defined(_SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A)
|
||
#undef _SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A
|
||
#endif
|
||
#endif
|
||
|
||
#if defined(_SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A)
|
||
#if defined(_ALPHATEST_ON)
|
||
#undef _ALPHATEST_ON
|
||
#endif
|
||
#endif
|
||
|
||
//--------------------------------------
|
||
// GPU Instancing
|
||
#pragma multi_compile_instancing
|
||
|
||
#pragma vertex ShadowPassVertex
|
||
#pragma fragment ShadowPassFragment
|
||
|
||
// Include base inputs and all other needed "base" includes
|
||
#include "Includes/Lux URP Flat Shaded Inputs.hlsl"
|
||
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Shadows.hlsl"
|
||
|
||
// Shadow caster specific input
|
||
float3 _LightDirection;
|
||
|
||
VertexOutput ShadowPassVertex(VertexInput input)
|
||
{
|
||
VertexOutput output = (VertexOutput)0;
|
||
UNITY_SETUP_INSTANCE_ID(input);
|
||
UNITY_TRANSFER_INSTANCE_ID(input, output);
|
||
|
||
#if defined(_ALPHATEST_ON)
|
||
output.uv.xy = TRANSFORM_TEX(input.texcoord, _BaseMap);
|
||
#endif
|
||
|
||
float3 positionWS = TransformObjectToWorld(input.positionOS.xyz);
|
||
float3 normalWS = TransformObjectToWorldDir(input.normalOS);
|
||
|
||
output.positionCS = TransformWorldToHClip(ApplyShadowBias(positionWS, normalWS, _LightDirection));
|
||
#if UNITY_REVERSED_Z
|
||
output.positionCS.z = min(output.positionCS.z, output.positionCS.w * UNITY_NEAR_CLIP_VALUE);
|
||
#else
|
||
output.positionCS.z = max(output.positionCS.z, output.positionCS.w * UNITY_NEAR_CLIP_VALUE);
|
||
#endif
|
||
return output;
|
||
}
|
||
|
||
half4 ShadowPassFragment(VertexOutput input) : SV_TARGET
|
||
{
|
||
UNITY_SETUP_INSTANCE_ID(input);
|
||
UNITY_SETUP_STEREO_EYE_INDEX_POST_VERTEX(input);
|
||
|
||
#if defined(_ALPHATEST_ON)
|
||
half mask = SAMPLE_TEXTURE2D(_BaseMap, sampler_BaseMap, input.uv).a;
|
||
clip (mask - _Cutoff);
|
||
#endif
|
||
|
||
return 0;
|
||
}
|
||
ENDHLSL
|
||
}
|
||
|
||
// Depth -----------------------------------------------------
|
||
|
||
Pass
|
||
{
|
||
Tags{"LightMode" = "DepthOnly"}
|
||
|
||
ZWrite On
|
||
ColorMask 0
|
||
Cull Off
|
||
|
||
HLSLPROGRAM
|
||
// Required to compile gles 2.0 with standard srp library
|
||
#pragma prefer_hlslcc gles
|
||
#pragma exclude_renderers d3d11_9x
|
||
#pragma target 2.0
|
||
|
||
#pragma vertex DepthOnlyVertex
|
||
#pragma fragment DepthOnlyFragment
|
||
|
||
// -------------------------------------
|
||
// Material Keywords
|
||
#pragma shader_feature _ALPHATEST_ON
|
||
|
||
#pragma shader_feature _SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A
|
||
|
||
#pragma shader_feature_local _ENABLEBASEMAP
|
||
#if !defined(_ENABLEBASEMAP)
|
||
#if defined(_ALPHATEST_ON)
|
||
#undef _ALPHATEST_ON
|
||
#endif
|
||
#if defined(_SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A)
|
||
#undef _SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A
|
||
#endif
|
||
#endif
|
||
|
||
#if defined(_SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A)
|
||
#if defined(_ALPHATEST_ON)
|
||
#undef _ALPHATEST_ON
|
||
#endif
|
||
#endif
|
||
|
||
//--------------------------------------
|
||
// GPU Instancing
|
||
#pragma multi_compile_instancing
|
||
|
||
#define DEPTHONLYPASS
|
||
#include "Includes/Lux URP Flat Shaded Inputs.hlsl"
|
||
|
||
VertexOutput DepthOnlyVertex(VertexInput input)
|
||
{
|
||
VertexOutput output = (VertexOutput)0;
|
||
UNITY_SETUP_INSTANCE_ID(input);
|
||
UNITY_TRANSFER_INSTANCE_ID(input, output);
|
||
UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(output);
|
||
|
||
#if defined(_ALPHATEST_ON)
|
||
output.uv.xy = TRANSFORM_TEX(input.texcoord, _BaseMap);
|
||
#endif
|
||
|
||
output.positionCS = TransformObjectToHClip(input.positionOS.xyz);
|
||
return output;
|
||
}
|
||
|
||
half4 DepthOnlyFragment(VertexOutput input) : SV_TARGET
|
||
{
|
||
UNITY_SETUP_INSTANCE_ID(input);
|
||
UNITY_SETUP_STEREO_EYE_INDEX_POST_VERTEX(input);
|
||
|
||
#if defined(_ALPHATEST_ON)
|
||
half mask = SAMPLE_TEXTURE2D(_BaseMap, sampler_BaseMap, input.uv.xy).a;
|
||
clip (mask - _Cutoff);
|
||
#endif
|
||
|
||
return 0;
|
||
}
|
||
|
||
ENDHLSL
|
||
}
|
||
|
||
// Meta -----------------------------------------------------
|
||
|
||
Pass
|
||
{
|
||
Tags{"LightMode" = "Meta"}
|
||
|
||
Cull Off
|
||
|
||
HLSLPROGRAM
|
||
// Required to compile gles 2.0 with standard srp library
|
||
#pragma prefer_hlslcc gles
|
||
|
||
#pragma vertex UniversalVertexMeta
|
||
#pragma fragment UniversalFragmentMeta
|
||
|
||
#define _SPECULAR_SETUP
|
||
|
||
// First include all our custom stuff
|
||
#include "Includes/Lux URP Flat Shaded Inputs.hlsl"
|
||
|
||
//--------------------------------------
|
||
// Fragment shader and functions
|
||
|
||
inline void InitializeStandardLitSurfaceData(float2 uv, out SurfaceData outSurfaceData)
|
||
{
|
||
half4 albedoAlpha = SampleAlbedoAlpha(uv, TEXTURE2D_ARGS(_BaseMap, sampler_BaseMap));
|
||
outSurfaceData.alpha = 1;
|
||
outSurfaceData.albedo = albedoAlpha.rgb * _BaseColor.rgb;
|
||
outSurfaceData.metallic = 0;
|
||
outSurfaceData.specular = _SpecColor;
|
||
outSurfaceData.smoothness = _Smoothness;
|
||
outSurfaceData.normalTS = half3(0,0,1);
|
||
outSurfaceData.occlusion = 1;
|
||
outSurfaceData.emission = 0;
|
||
}
|
||
|
||
// Finally include the meta pass related stuff
|
||
#include "Packages/com.unity.render-pipelines.universal/Shaders/LitMetaPass.hlsl"
|
||
|
||
ENDHLSL
|
||
}
|
||
|
||
// End Passes -----------------------------------------------------
|
||
|
||
}
|
||
FallBack "Hidden/InternalErrorShader"
|
||
CustomEditor "LuxURPUniversalCustomShaderGUI"
|
||
} |